NEW Free Software: Stars Debustifier v0.1 (close finished tournaments)
02-04-2009
, 09:25 PM
Quote:
Code:
;DebustifierAHK v0.1 by Entropic on the 2p2 forums (http://forumserver.twoplustwo.com/)
#Persistent
KickMessage = MSG_TABLE_SIT_KICK ;This is the line we're looking for in the log file
hwnd = ;Handle of the window we're trying to close
SetTimer, FileCheck ;We use a timer to read the file as it changes
;----------------------------------------------------------------------
;----------------------------------------------------------------------
if A_OSVersion in WIN_VISTA
{
LogFilePath = %A_AppData%\Pokerstars\PokerStars.log.0
}
else
{
LogFilePath = %A_ProgramFiles%\Pokerstars\PokerStars.log.0
}
;----------------------------------------------------------------------
;If you installed PokerStars in a custom directory Comment out the 8 lines above (aside from #Persistent)
;uncomment the one below. Then modify the line below to the path to your PokerStars.log.0 file
;LogFilePath = C:\PokerStars\PokerStars.log.0
;----------------------------------------------------------------------
;This function opens the PokerStars.log.0 file and only looks at the last few lines of it
Debustify()
{
global KickMessage
global LogFilePath
global hwnd
IfExist, %LogFilePath% ;The log file does exist
{
FileContents := Tail(500, LogFilePath)
}
else ;Log file doesn't exist, we're in trouble, exit
{
Msgbox, "Path to logfile "%LogFilePath%" does not exist"
ExitApp
}
;The string we're looking for looks something like this
;MSG_TABLE_SIT_KICK 00010FE0 'You finished the tournament in 7th place,
;We check each each of the lines we pulled from the file above
Loop, parse, FileContents, `n, `r
{
hwnd =
if InStr(A_LoopField, KickMessage) ;If we find the kick message a tourney has ended
{
hwnd := SubStr(A_LoopField, 19, 9) ;Parse out the handle of the window so we can close it
hwnd := "0x" . hwnd ;Put it in autohotkey format 0x000F1939
StringReplace, hwnd, hwnd, %A_SPACE%,,
PostMessage, 0x10, 0, 0,, ahk_id %hwnd% ;Close the window
}
}
}
;Tail function by Laszlo of the AutoHotkey forums
Tail(k,file) ; Return the last k lines of file
{
Loop Read, %file%
{
i := Mod(A_Index,k)
L%i% = %A_LoopReadLine%
}
L := L%i%
Loop % k-1
{
IfLess i,1, SetEnv i,%k%
i-- ; Mod does not work here
L := L%i% "`n" L
}
Return L
}
;This function/label compares the size of the file now to the last time it checked
;If they're different the file has been updated and we need to scan for finished tournaments again
FileCheck:
FileGetSize Size, %LogFilePath%
If Size0 >= %Size%
Return
If Size0 = ;No changes to the file
{
Size0 = %Size%
Return
}
Size0 = %Size% ;File has been changed, store the new size
Debustify() ;Call the function to check the log file for new finished tournaments
Return
02-05-2009
, 02:45 AM
Thanks for sharing it.
