Code:
/*
QuickNotes by Respawn
Makes note taking with Hold'em Manager more efficient
2+2 thread: http://
Feel free to contribute additions and improvements to the code in the 2+2 thread.
Contains elements from:
- HEM Shortcuts by Hood
http://forumserver.twoplustwo.com/45/software/hem-shortcuts-ahk-433431/
- Keyboard Redirect by _dave_
http://overcards.com/wiki/moin.cgi/KeyboardRedirect
*/
; SETUP AND CONFIGURATION
; --------------------------------------------------------
;Script configuration
#NoEnv ; Avoids checking empty variables to see if they are environment variables (recommended for all new scripts).
#SingleInstance force ; Determines whether a script is allowed to run again when it is already running.
#Include %A_ScriptDir% ; Changes the working directory for subsequent #Includes and FileInstalls.
Critical, On ; Prevents the current thread from being interrupted by other threads.
SendMode, Input ; Makes Send synonymous with SendInput or SendPlay rather than the default (SendEvent). Also makes Click and MouseMove/Click/Drag use the specified method.
SetBatchLines, -1 ; Determines how fast a script will run (affects CPU utilization). Use SetBatchLines -1 to never sleep (i.e. have the script run at maximum speed).
SetTitleMatchMode, 2 ; A window's title can contain the specified string anywhere inside it to be a match.
SetWorkingDir, %A_ScriptDir% ; Changes the script's current working directory.
; Change these to pixel x/y and width/height for the notes windows
HEMNOTES_X := 0
HEMNOTES_Y := 770
HEMNOTES_W := 420
HEMNOTES_H := 282
FTPNOTES_X := 420
FTPNOTES_Y := 770
FTPNOTES_W := 420
FTPNOTES_H := 282
; Frequency to check for new windows to move them
SetTimer, MoveHEMNotesLoop, 10
SetTimer, MoveFTPNotesLoop, 250
; Identifiers for each window.
GroupAdd, HEMNotes, , asdfas ; The hidden text "asdfas" identifies note windows. May break in the future.
GroupAdd, FTPNotes, Player Note
;Menu, Tray, Icon, QuickNotesGreen.ico
;Menu, Tray, Icon, QuickNotesPurple.ico
; WINDOW MOVEMENT / RESIZING / NOTES TAG & TIMESTAMP
; --------------------------------------------------------
FileRead, NotesTagList, NotesTagList.txt
StringTrimRight, NotesTagList, NotesTagList, 1 ; removes the comma at the end of the list
MoveHEMNotesLoop:
WinGet, hemnotesid, ID, ahk_group HEMNotes
if (hemnotesid) {
if (!movedhemnotes) {
movedhemnotes := true
FormatTime, NotesTimeStamp, ,yy/MM' ' ; e.g. 10/01 for January 2010
WinMove ahk_id %hemnotesid%,, %HEMNOTES_X%, %HEMNOTES_Y%, %HEMNOTES_W%, %HEMNOTES_H%
WinActivate, ahk_id %hemnotesid%
SetControlDelay, -1
SetKeyDelay, , 15
ControlFocus, RichEdit20A1, ahk_id %hemnotesid%
ControlGetText, HEMNotesText, RichEdit20A1, ahk_id %hemnotesid%
if HEMNotesText contains %NotesTagList%
{
IfInString, HEMNotesText, %NotesTag%
{
ControlSend, RichEdit20A1, ^{End}, ahk_id %hemnotesid%
Control, EditPaste, `n%NotesTimeStamp%, RichEdit20A1, ahk_id %hemnotesid%
}
else
{
ControlSend, RichEdit20A1, ^{End}, ahk_id %hemnotesid%
Control, EditPaste, `n---`n%NotesTag%`n%NotesTimeStamp%, RichEdit20A1, ahk_id %hemnotesid%
}
}
else
{
Control, EditPaste, %NotesTag%`n%NotesTimeStamp%, RichEdit20A1, ahk_id %hemnotesid%
AddToNotesTagList()
}
}
} else {
movedhemnotes := false
DetermineNotesTag()
}
return
MoveFTPNotesLoop:
WinGet, ftpnotesid, ID, ahk_group FTPNotes
if (ftpnotesid) {
if (!movedftpnotes) {
movedftpnotes := true
WinMove ahk_id %ftpnotesid%,, %FTPNOTES_X%, %FTPNOTES_Y%, %FTPNOTES_W%, %FTPNOTES_H%
WinActivate, ahk_id %ftpnotesid%
}
} else {
movedftpnotes := false
}
return
DetermineNotesTag() {
global
MouseGetPos, , , WindowUnderMouse
WinGetTitle, Tablename, ahk_id %WindowUnderMouse%
WinGetClass, HoverClass, ahk_id %WindowUnderMouse%
IfInString, Tablename, overlay ; [Tablename]overlay = HUD on top of table under mouse
StringTrimRight, Tablename, Tablename, 7 ; removes "overlay" (= 7 characters from the right)
; HEM uses "(ante deep)", not "(ante, deep)" and "(heads up deep)", not "(heads up, deep) like Full Tilt does
IfInString, Tablename, (
{
ParenthesisPos := InStr(Tablename, "(")
StringLeft, Tablename, Tablename, ParenthesisPos
}
; For PartyPoker: isolate the number in the title
RegExMatch(Tablename, "[0-9]{5,}", PartyNumber) ; requires the number to be at least 5 digits long, prevents a match with the first number in e.g. "$1/$2"
if (PartyNumber)
Tablename = %PartyNumber%
WinGetTitle, Title, %Tablename%, , overlay, 2+2 ; disregards windows that contain "overlay" in their title, i.e. disregards HUD windows
WinGetClass, WindowClass, %Title%, , overlay, 2+2 ; exclude windows containing the text "2+2" so that HEM hand history windows are disregarded
; HEM removes underscores from table titles, causes problems with tables like "Air_Nav", "al_lupner", "bob_tiger", don't know what happens when titles contain other special characters
; might want to use a matchlist containing several special characters and use something like "if Title contains %SpecialCharacter%", remember "-" is in all titles
if (!Title) { ; if there is no matching Title
if HoverClass = Afx:00400000:20:00010013:00000000:00000000 ; if hovering over HUD window
{
if (Tablename) { ; this prevents the loop from starting when hovering the mouse over a HUD popup
Loop, 5 { ; sometimes the loop starts when it's not supposed to. cause unknown. this prevents infinite loop iterations.
StringLeft, ShortTablename, Tablename, %A_Index%
TrayTip, Looking for underscore, Current loop iteration: %A_Index%`nLooking for underscore in: [%Title%], 10, 2 ; this is in here temporarily to help with finding the cause for unwanted starting of the loop
WinGetTitle, Title, %ShortTablename%, , overlay
IfInString, Title, _
{
TrayTip, Looking for underscore, Current loop iteration: %A_Index%`nUnderscore found in: [%Title%], 10, 1 ; this is in here temporarily to help with finding the cause for unwanted starting of the loop
break
}
}
}
}
}
DetermineStakes() ; Stakes?
DetermineGame() ; NL or PLO?
DetermineSeatLimit() ; HU, 6m or FR?
NotesTag = %Stakes%%Game% %SeatLimit% ; e.g. "100NL FR"
}
DetermineStakes() {
global
if Title = Holdem Manager Replayer ; HEM uses a format like this: $1/2
{
WinGetText, Title, %Title%
StringGetPos, TablePos, Title, Table, R
StringLeft, BB, Title, %TablePos%
SlashPos := InStr(BB, "/", 0, 0) + 1 ; searches from right to left
StringMid, BB, BB, SlashPos
}
else if (PartyNumber) ; PartyPoker uses a format like this: 0,50 $/1 $ ; else if WindowClass = #32770
{
SlashPos := InStr(Title, "/", 0,0) + 1
StringMid, BB, Title, SlashPos
}
else ; Full Tilt and PokerStars use a format like this: $1/$2
{
SlashPos := InStr(Title, "/") + 2
StringMid, BB, Title, SlashPos
IfInString, BB, Ante ; Ante table?
{
StringGetPos, AntePos, BB, Ante
StringLeft, BB, BB, %AntePos% ; only use text left of "Ante" in order to avoid problems with determining stakes correctly in games with antes such as "0.2"
}
}
IfInString, BB, `,
StringReplace, BB, BB, `,, . ; replaces "," with "." to support sites that use "," as decimal point
IfInString, BB, 0.0 ; e.g. 0.05 = 5NL
{
StringTrimLeft, BB, BB, 3 ; removes "0.0"
StringLeft, BB, BB, 1 ; uses the first character starting from the left of what remains of the string "BB" after "0.0" has been removed, e.g. "5"
Stakes = %BB%
}
else IfInString, BB, 0.1 ; 0.1 = 10NL, cannot use "0." because HEM uses "0.1" and not "0.10" for $0.05/$0.10 games
{
StringTrimLeft, BB, BB, 2 ; removes "0."
StringLeft, BB, BB, 1
Stakes = %BB%0
}
else IfInString, BB, 0. ; e.g. 0.25 = 25NL
{
StringTrimLeft, BB, BB, 2 ; removes "0."
StringLeft, BB, BB, 2 ; uses the first two characters starting from the left of what remains of the string "BB" after "0." has been removed, e.g. "25"
Stakes = %BB%
}
else IfInString, BB, 00 ; e.g. 100 = 10kNL
{
StringLeft, BB, BB, 1
Stakes = %BB%0k
}
else IfInString, BB, 0 ; e.g. 10 = 1kNL
{
StringLeft, BB, BB, 1
Stakes = %BB%k
}
else IfNotInString, BB, 0 ; e.g. 1 = 100NL
{
StringLeft, BB, BB, 1
Stakes = %BB%00
}
}
DetermineGame() {
global
if Title contains No Limit Hold'em,NL Hold'em,NL Table ; Full Tilt/PokerStars, PartyPoker, HEM
Game = NL
else Game = PLO ; have not tested PLO in HEM
}
DetermineSeatLimit() {
global
IfInString, Title, heads up ; Full Tilt format
SeatLimit = HU
else IfInString, Title, 1 on 1 ; PokerStars format
SeatLimit = HU
else IfInString, Title, 6 max ; PartyPoker and PokerStars don't put "6 max" or similar in the window title. No way to differentiate between 6m and FR for now :(
SeatLimit = 6m
else SeatLimit = FR ; change this to 6m if you primarily play 6m on PartyPoker or PokerStars
}
AddToNotesTagList() {
global
if NotesTagList not contains %NotesTag%
{
NotesTagList = %NotesTag%,%NotesTagList%
FileAppend, %NotesTag%`,, NotesTagList.txt ; "`," indicates a literal comma
}
}
; NOTES HOTKEYS
; --------------------------------------------------------
Esc:: ; pressing Esc will hit the cancel button in the HEM notes window
SetControlDelay -1
ControlClick, Cancel, ahk_id %hemnotesid%
return
!1::SendInput %NotesTag%
)
)
