Quote:
Originally Posted by Antidote
I have an AHK request. I do not know if it is feasible, but if someone could do it for me, I would pay them at least $50. Here is what I want:
I play on many different sites. I always strive to game-select well by leaving games that do not have fish as well as checking the lobbies of the different sites I play on for better games. Sometimes, I forget to check the lobbies of certain sites or I do not leave tables when I should. I am looking for an AHK script that can help remind me by doing the following:
Once launched, the AHK script would have a small GUI that has one action and a checkbox. For example, an action would say something like "Start 2 new tables of 10/20 HUNL on Full Tilt." Once checked, that action would disappear and a new one would come up with a checkbox. For example, "Start 2 new tables of 10/20 HU NL on Chili Poker." Once I checked this box, a new action would come up which I could then check when completed, and this process would keep repeating itself.
I would find this to be very helpful, since I often forget to start HU tables on certain sites or to check the lobbies for good 6-max games. One other thing I would like the script to do would be to have a repeat function for part of the actions. For example, there are basically 2 components to playing: Preparation, and While Playing.
Preparation components would be stuff like:
1. Launch The Opener.
2. Log in to Party Poker.
3. Log in to Full Tilt.
etc.
While Playing components would be stuff like:
1. Check all tables that are you playing on for fish. If a table is only regulars, leave that table.
2. Search the PokerStars lobby for 10/20 PLO games.
etc.
Now the preparation actions only have to be done once, but the while playing actions are done continuously and for this reason, I would like them to loop. For example, let's say I have 10 while playing actions. When I complete #10, the AHK script would go back to #1.
Code:
;Software that reminds you of what to do.
;preparations runs first and one time only.
;When all preparations has ran the actions
;for "while playing" itterats as long as
;the script is open.
;==========================================================================================================
;================================== EDIT THIS =============================================================
;==========================================================================================================
preparation1 = Launch The Opener.
preparation2 = Log in to Party Poker.
preparation3 = Log in to Full Tilt.
whilePlaying1 = Check all tables that are you playing on for fish. If a table is only regulars, leave that table.
whilePlaying2 = Search the PokerStars lobby for 10/20 PLO games.
;==========================================================================================================
;==========================================================================================================
;==========================================================================================================
Loop
{
if !preparation%A_Index%
{
totalPreparations := A_Index - 1
break
}
}
Loop
{
if !whilePlaying%A_Index%
{
totalWhilePlaying := A_Index - 1
break
}
}
component := 1
action := 1
Gui, Font, s14, Verdana
Gui, Add, Text, x10 y10 w335 h95 vactionText, %preparation1%
Gui, Add, Button, x10 y115, Check
Gui, Add, Text, x120 y120 w225 vactionCounter, Preparation %action%/%totalPreparations%
Gui, Show,h165 w350, Action checker
return
;=====================================================
ChangeAction(component,action)
{
global
if (component = 1)
{
text := preparation%action%
Guicontrol,,actionCounter, Preparation %action%/%totalPreparations%
}
else
{
text := whilePlaying%action%
Guicontrol,,actionCounter, While playing %action%/%totalWhilePlaying%
}
GuiControl,,actionText, %text%
return
}
;=====================================================
ButtonCheck:
action++
if (component = 1)
{
if !preparation%action%
{
component := 2
action := 1
}
}
else
{
if !whilePlaying%action%
{
action := 1
}
}
ChangeAction(component,action)
return
;=====================================================
GuiClose:
ExitApp
;=====================================================