AHK Code Request: Highlight Table - Page 2 - Poker Software -- Two Plus Two Poker Forums

Two Plus Two Forums Online Poker Sites & Marketplaces Poker Software

AHK Code Request: Highlight Table

Post Reply Subscribe

...

Page 2 of 2

1 2

Page 2 of 2

1 2

07-07-2010 , 04:15 AM

#26

nutfile

stranger

Join Date: Mar 2010 Posts: 2

Quote:

Originally Posted by greg nice

awesome job man.

agree

Quote

07-08-2010 , 07:40 AM

#27

madlion

old hand

Join Date: Jan 2009 Posts: 1,550

Cool bro, I never used table highlighters cause the borders look like ass but this is the nuts, high5 Roland

Quote

07-09-2010 , 02:58 PM

#28

ace23spades

centurion

Join Date: Dec 2008 Posts: 164

nice work. is there a script that "colorboards" by buy in level, mtt, sng...
like: all 18 man = red boarder, 180=blue, mtt=green?

Quote

07-25-2010 , 07:59 PM

#29

lamb

centurion

Join Date: Jun 2010 Posts: 118

Really nice work, thank you. Tried to use it and I have one question: active table is highlighted and not active is not, after you acted on active table and its turn of non highlighted table to act, in this case both table are highlighted and only after action on second one first becomes dark. Is it OK?\
p.s. Used it on FTP.

Quote

07-30-2010 , 03:41 PM

#30

Roland

veteran

Join Date: Mar 2005 Posts: 2,839

Quote:

Originally Posted by lamb

This happens because the FullTilt software will not activate/focus a table when action is required, but just make it topmost without activating it. Unfortunately my script won't work so well in this case.

I did notice that dialogs were not being handled properly on FullTilt, so I've updated the script a little.

Code:

/**
 * Creates a full-screen, transparent, click-through-able window and
 * monitors changes in the active window, pushing inactive windows
 * under the full-screen window. The effect is that the active window
 * stands out more, while inactive windows appear dimmed.
 *
 * NOTE: 
 *  • Press Shift+Win+Escape to exit.
 *  • You can modify transparency and color at top of script.
 *
 * KNOWN ISSUES:
 *  • The FullTilt software will not activate a table when action is
 *    required, but instead make it AlwaysOnTop. As the script only
 *    reacts when the active window changes, this throws it off. Thus
 *    both tables will be highlighted (until you click on the table
 *    needing action).
 *
 * CHANGELOG:
 *   • [30/07/2010] Check a windows ownder as opposed to its parent.
 *     This should work better with a lot of dialogs (e.g. FullTilt).
 *
 * @author Roland (roland@overcards.com)
 * @date   24 June 2010
 * @AHK    1.0.48.05.L52
 * @see    http://www.autohotkey.com/forum/viewtopic.php?p=206589#206589
 */

#NoEnv
#SingleInstance force
SetWinDelay -1          ; we don't want any delays

TRANSPARENCY := 150
COLOR        := 0x000000

SysGet, monitorCount, MonitorCount
Loop % monitorCount {
    Gui, %a_index%: Default
    Gui, +Toolwindow -Caption +Lastfound
    Gui, Color, % COLOR
    WinSet, ExStyle, +0x00000020
    WinSet, Transparent, % TRANSPARENCY
    SysGet, mon, MonitorWorkArea , % a_index
    Gui, Show
    , % "x" monLeft " y" monTop " w" monRight-monLeft 
      . " h" monBottom-monTop " NoActivate"
  }

; keep monitoring change in active window:
Loop {
    hwndLast:=WinExist("A")   ; get handle of active window
    WinWaitNotActive          ; wait for it to become not-active
    ; this is necessary due to "SetWinDelay -1" above... we need to
    ; wait until a new active window exists (sometimes there is no
    ; new active window yet):
    while !WinExist("A")
      Sleep 10
    ; if the new active window is owned by the last active
    ; window, we don't want to change anything:
    ; 4=GW_OWNER (http://msdn.microsoft.com/en-us/library/ms633515.aspx)
    hOwner:=DllCall("GetWindow", "uint", WinExist("A"), "uint", 4)
    ; if the active window is not owned by the previously active window,
    ; push the previously active window under the "dimmer":
    ifNotEqual, hOwner, % hwndLast, WinSet, Bottom,, ahk_id%hwndLast%
  }
return

+#esc::ExitApp

Quote

08-10-2010 , 06:14 AM

#31

Flip512

newbie

Join Date: Aug 2008 Posts: 19

Roland, thank you for this script. I just tried it out, and it is fantastic. I also noticed that to prevent two full tilt tables from being highlighted at once, all you need to do is turn off the "Display Table on Action" setting (found in the Options menu in the main lobby).

The one weird thing that I noticed, however, is window positioning after deactivation. I'm going to describe the issues below just for the sake of putting them out there; the important thing is that two tables aren't un-dimmed simultaneously.

So there are two specific examples of weird window positioning that I can think of. First, after I leave my browser window (chrome) for a poker table, one of 2 things will happen. Most of the time, the chrome window will be moved not just underneath the dimmer, but underneath all other windows as well. Sometimes, however, it will be placed below only the newly-activated table (ie, neither the browser nor poker table will be dimmed, and the poker table will be active).

If there's anything I'd like to fix, it would be getting recently-deactivated windows to dim, but also stay on top of all other dimmed windows.

Anyway, thanks again. Ill be tooling around with this for the next couple of days, and will report back if I figure anything out.

Quote

08-11-2010 , 07:28 PM

#32

Baobhan-Sith

Pooh-Bah

Join Date: Oct 2009 Posts: 4,279

I experienced the same with PS. Also, there seems to be a little bug for multiple monitors: sometimes it doesn't dim the former active window when a window on the other monitor pops up. The inactive but undimmed window stays undimmed until it's activated and deactivated again. Not a big deal for me but I thought I let you know.

Quote

09-16-2010 , 09:58 AM

#33

Soulfan

newbie

Join Date: May 2009 Posts: 33

hey dudes....is there any way if a table pop ups adn while ure thinking another one pop ups to be both highlighted?? i mean all the tables that poped up but u did not action to be highlighted....best regards

Quote

09-16-2010 , 03:55 PM

#34

Soulfan

newbie

Join Date: May 2009 Posts: 33

ps i play on ipoker

Quote

12-02-2010 , 07:47 AM

#35

mckrogh

Carpal \'Tunnel

Join Date: Jan 2009 Posts: 6,495

Can someone help me?

This script is working fine, but sometimes when going to postflop it dosnt highlight table?

What could be wrong?

Quote

12-03-2010 , 02:32 PM

#36

mckrogh

Carpal \'Tunnel

Join Date: Jan 2009 Posts: 6,495

Quote:

Originally Posted by Roland

Like this?

Code:

#NoEnv
#SingleInstance force

f1::
drawFrameAroundWin(WinExist("a"), "Red", 4, 1, true)
return

; mode=1: Draw frame around whole window
; mode=2: Draw frame around client area
; if inside is true, the frame will be drawn towards
; the "inside" of the table instead of around it, i.e. it
; will overlap with the table
drawFrameAroundWin(win, color, thickness, mode=1, inside=false, gui=0) {
t:=thickness
ifEqual, mode, 1, {
    WinGetPos, x, y, w, h, ahk_id%win%
    if inside
      x+=thickness, y+=thickness, w-=thickness*2, h-=thickness*2
    return drawFrame(x, y, w, h, color, thickness, gui)
  } else ifEqual, mode, 2, {
    getClientRect(x, y, w, h, win)
    if inside
      x+=thickness, y+=thickness, w-=thickness*2, h-=thickness*2
    return drawFrame(x, y, w, h, color, thickness, gui)
  } else {
    msgbox No such mode!
  }
}

drawFrame(x, y, w, h, color, thickness, gui=0) {
t:=thickness
x1:=0, y1:=0
x2:=w+t*2, y2:=y1
x3:=x2, y3:=h+t*2
x4:=x1, y4:=y3
x5:=x1, y5:=y1
x6:=t, y6:=t
x7:=x2-t, y7:=y6
x8:=x7, y8:=y3-t
x9:=x6, y9:=y8
x10:=x6, y10:=y6
Loop 10
  region.=x%a_index% "-" y%a_index% " "
gui:=gui ? gui : freeGui()
Gui, %gui%:default
Gui, +lastfound +alwaysOnTop +toolwindow -caption
Gui, Color, % color
x:=x-t, y:=y-t, w:=w+t*2, h:=h+t*2
Gui, Show, x%x% y%y% w%w% h%h% hide, Frame (Gui #: %gui%)
WinSet, Region, % region
Gui, Show, noActivate
return gui
}

; finds the next free gui
freeGui(startIdx=0) { 
Loop % (99-startIdx) {
    startIdx++
    Gui, %startIdx%: +lastfoundExist 
    If ! WinExist() 
      return startIdx 
  } 
} 

/**
 * Finds the "client rectangle" of a window, i.e. the area of
 * the window not including borders, titlebar, menus, etc.
 * 
 * @param x     <int>   Receives the x-coordinate of the window.
 * @param y     <int>   Receives the y-coordinate of the window.
 * @param w     <int>   Receives the width of the window.
 * @param h     <int>   Receives the height of the window.
 * @param hwnd  <hwnd>  Window handle. If blank, the Last Found Window will be used.
 * @author Adapted from code by Sean. Modified and updated to use 
 *    NumGet()/NumPut() by Roland.
 * @see http://msdn.microsoft.com/en-us/library/ms633503(VS.85).aspx
 * @see http://msdn.microsoft.com/en-us/library/aa931003.aspx
 */
getClientRect(byRef x="", byRef y="", byRef w="", byRef h="", hwnd=0) {
hwnd:=hwnd ? hwnd : WinExist()    ; use LFW if no hwnd given
VarSetCapacity(rt, 16)            ; alloc. mem. for RECT struc.
VarSetCapacity(pt, 8, 0)          ; alloc. mem. for POINT struc.
DllCall("GetClientRect" , "uint", hwnd, "uint", &rt)
DllCall("ClientToScreen", "uint", hwnd, "uint", &pt)
x:=NumGet(pt, 0, "int"), y:=NumGet(pt, 4, "int")
w:=NumGet(rt, 8, "int"), h:=NumGet(rt, 12, "int")
}

Could someone please help me get this thing working again?

Quote

01-04-2011 , 12:14 AM

#37

themandude

veteran

Join Date: Mar 2006 Posts: 2,252

I tried it briefly and it worked fine, seems like a cool concept. The problem for me is it creates lag, slows my system down. When i close the AHK my systems crisp again.

Quote

04-04-2011 , 11:08 AM

#38

stusmokes

grinder

Join Date: Feb 2010 Posts: 403

http://techsalsa.com/dim-windows-oth...active-window/

Quote

04-05-2011 , 12:06 PM

#39

2stacks

centurion

Join Date: Mar 2011 Posts: 104

Quote:

Originally Posted by stusmokes

http://techsalsa.com/dim-windows-oth...active-window/

This works for me when using:

FTP
HEM
PlaceMint
PokerShortcuts

Quote

11-13-2011 , 01:11 PM

#40

Andrea81

stranger

Join Date: Nov 2011 Posts: 1

Hi everyoone,
I'd like to write a little script for multitabling
I play 20 table simultaneously (SnG)
and I'd like automate highlight in red any table on level is > 200-400.
In the titlebar of any window of "Pokerstars" there is write amount of BigBlind (for example window title name: €10 NL Hold'em [Turbo] - Blinds €200/€400)
I tried 3 day to use AHK but I don't know do it

I'm checking on web similiar script, but I try this comunity

I hope someone can help me
(sorry for my poor english)

Andrea from Italy

Quote

04-02-2013 , 03:40 PM

#41

Barthold

centurion

Join Date: Oct 2009 Posts: 185

Hi uber leet Roland or someone who can code in this scripting language

Maybe it's out there already, but I haven't found it, would be willing to pay some bucks for it, maybe other peeps to, just +1 in comments! ; pretty easy script:

color code tables based on buyin amount for stars (and fulltilt!! (and party!))

It would be great to read out the text in titlebar and convert buyin amount to number so you can define a range for one specific color; e.g. blue=<25 ... so all table below 25$ buyin will be blue

Quote

04-03-2013 , 10:29 AM

#42

I_Am_No_Doctor

Guest

Posts: n/a

Quote:

Originally Posted by Barthold

This might work for you:

I just created simple AHK scripts that automatically changes the background or table felt color.

For the Stars backgrounds I used & loaded the Blacktop background into Paint.net and edited just the area around the BET / Raise buttons.

I use bright green for rebuys (less $2) (3X rebuys)
Blue for 2-6 bucks
Purple for greater then $6

I saved them each under these backgrounds

Nova, Metal & Poker Room and just used this AHK script for each background
to be selected

NumPad4::
Click right
click 28, 106
return

Table colors for larger satellites seats or buyins

This for each custom Table color

NumPad9::
Click right
click 91, 163
click 201, 79
click 43, 306
return

You need to use the window Spy for your XY values on your monitor setups.

So every time a new table starts just color it with a key. I find that it's less distracting to have the colors around the bet options then to have every table border colored on your screen.

Color the table again if you get to FT.

You might find this works for ya

Last edited by I_Am_No_Doctor; 04-03-2013 at 10:40 AM.

Quote

04-07-2013 , 09:56 AM

#43

Barthold

centurion

Join Date: Oct 2009 Posts: 185

Quote:

Originally Posted by I_Am_No_Doctor

Thanks, do you have to redo the work when Stars update there themes ? I'm trying to find a way to directly set properties of a window. I'm going to try to make something myself, when I have the time, I will post it here

Quote

04-09-2013 , 09:58 AM

#44

I_Am_No_Doctor

Guest

Posts: n/a

Quote:

Originally Posted by Barthold

I make copies and overwrite any files that Stars reverts back to original form after an update.

Quote

06-03-2013 , 06:31 AM

#45

zamb3zi

newbie

Join Date: Jun 2013 Posts: 16

Thanks for this Roland. The only problem I had with the dimmer script is that when a window is inactivated, it gets pushed below all other windows. For example a browser in the background. To fix this, I modified it so that when a new window is made active, the dimmer window is placed exactly underneath it. This allows me to keep all my poker tables above any background windows so I can keep an eye on them when they are inactive.

Code:

/**
 * Creates a full-screen, transparent, click-through-able window and
 * monitors changes in the active window, pushing inactive windows
 * under the full-screen window. The effect is that the active window
 * stands out more, while inactive windows appear dimmed.
 *
 * NOTE: 
 *  • Press Shift+Win+Escape to exit.
 *  • You can modify transparency and color at top of script.
 *
 * KNOWN ISSUES:
 *  • The FullTilt software will not activate a table when action is
 *    required, but instead make it AlwaysOnTop. As the script only
 *    reacts when the active window changes, this throws it off. Thus
 *    both tables will be highlighted (until you click on the table
 *    needing action).
 *
 * CHANGELOG:
 *   • [30/07/2010] Check a windows ownder as opposed to its parent.
 *     This should work better with a lot of dialogs (e.g. FullTilt).
 *
 * @author Roland (roland@overcards.com)
 * @date   24 June 2010
 * @AHK    1.0.48.05.L52
 * @see    http://www.autohotkey.com/forum/viewtopic.php?p=206589#206589
 */

#Persistent
#SingleInstance force
SetBatchLines,-1
SetWinDelay -1          ; we don't want any delays

DIMMER_TRANSPARENCY := 75
DIMMER_COLOR        := 0x000000

SysGet, monitorCount, MonitorCount
Loop % monitorCount {
    Gui, %a_index%: Default
    Gui, +Toolwindow -Caption +Lastfound
    Gui, Color, % DIMMER_COLOR
    WinSet, ExStyle, +0x00000020
    WinSet, Transparent, % DIMMER_TRANSPARENCY
    SysGet, mon, MonitorWorkArea , % a_index
    Gui, Show
    , % "x" monLeft " y" monTop " w" monRight-monLeft 
      . " h" monBottom-monTop " NoActivate"
	dimmer%a_index% := WinExist()
}

; keep monitoring change in active window:
Loop {
    hwndLast := WinExist("A")   ; get handle of active window
    WinWaitNotActive            ; wait for it to become not-active
    ; this is necessary due to "SetWinDelay -1" above... we need to
    ; wait until a new active window exists (sometimes there is no
    ; new active window yet):
    while ! hwnd := WinExist("A")
      Sleep 10
    ; if the new active window is owned by the last active
    ; window, we don't want to change anything:
    ; 4=GW_OWNER (http://msdn.microsoft.com/en-us/library/ms633515.aspx)
    hOwner := DllCall("GetWindow", "uint", hwnd, "uint", 4)
    ; if the active window is not owned by the previously active window,
    ; push the previously active window under the "dimmer":
    ; ifNotEqual, hOwner, % hwndLast, WinSet, Bottom,, ahk_id%hwndLast%
	if hOwner != hwndLast
	{
		Loop % monitorCount {
		  DllCall("SetWindowPos", "uint", dimmer%a_index%, "uint", hwnd, "int", "0", "int", "0", "int", "0", "int", "0"  , "uint", "19") ; 19 = NOSIZE | NOMOVE | NOACTIVATE ( 0x1 | 0x2 | 0x10 )
		}
	}
 }