notitle bar AHK on pokerstars, help please :( - Page 3

From what I make out if we create the layout manually in placemint or the user.ini which is x larger than our current layout (where x = the size of the title bar and borders).

Then when the table is shrunk it will be the size we require?

I'll let you know how I get on, but I don't understand why this happens now and why with XP I had no problems

Quote

12-04-2009 , 10:47 AM

#52

Exar_Kun

adept

Join Date: May 2005 Posts: 1,198

By some miracle I got it to work; unfortunately I don't really know how.
I had made multiple custom layouts which tell the tables how big they should be and where the should be located, but also used placemint.

I wish I could help but I suddenly chose an old custom layout that I had saved from way back with big tables, and then the combination of placemint it worked perfectly.

Quote

12-04-2009 , 10:48 AM

#53

Exar_Kun

adept

Join Date: May 2005 Posts: 1,198

ZARAUSTRA nice card mod for pokerstars, where did you get it from?

Quote

12-04-2009 , 12:52 PM

#54

Exar_Kun

adept

Join Date: May 2005 Posts: 1,198

Maximus thanks for your help, I think I managed to solve the problem even though im not 100% sure whats going on.

I strip the borders completely, arrange the tables manually how I like and then save the layout using pokerstars.

However like other users here they had the problem that the table image would be screwed, but I found out that if you disengage the custom layout and then engage it again (I suppose reset) then it suddenly worked like I saw in your video.

Occasionally during play today a new table would open and the image would be screwed up, but I simply turned off the layout and turned it back on again and it worked again.

I do however use placemint, and the only reason I use the custom layout is to ensure that the tables are displayed the correct size.

Hope this helps the other users.

Quote

12-04-2009 , 03:49 PM

#55

Max1mums

old hand

Join Date: Aug 2009 Posts: 1,700

You shouldn't change size but coordinates only! PM me your [Layout] digit string.

Last edited by Max1mums; 12-04-2009 at 04:17 PM.

Quote

12-04-2009 , 04:45 PM

#56

Exar_Kun

adept

Join Date: May 2005 Posts: 1,198

I can do but right now its working perfectly apart from occasionally (rarely) having to reset table layout...

Quote

12-04-2009 , 05:05 PM

#57

Max1mums

old hand

Join Date: Aug 2009 Posts: 1,700

Ok, nvm then.

Quote

12-11-2009 , 11:32 AM

#58

cubew00t

stranger

Join Date: Nov 2009 Posts: 4

I just discovered this great script yesterday and after the latest Stars update it stopped working!

Ironic. Any fixes?

Quote

12-11-2009 , 12:03 PM

#59

Max1mums

old hand

Join Date: Aug 2009 Posts: 1,700

Well it is still working for me (XP), what doesn't work exactly?

Quote

12-11-2009 , 01:52 PM

#60

cubew00t

stranger

Join Date: Nov 2009 Posts: 4

Windows 7 here, taking into account your comment, I ran it in xp compatibility mode and it works, thanks!

Quote

12-13-2009 , 11:37 PM

#61

jonwies

old hand

Join Date: Jan 2009 Posts: 1,245

So I'm trying to get this to work with full tilt (Windows 7), and I really like the way it is sizing the tables etc, but the problem is when the title bars are removed almost none of the buttons work... I can't re-tile, take a seat, click bet fold or anything...

Any ideas?

Right after the title bar disappears, I can use the buttons really quickly and tile the tables, but after a few seconds nothing seems to work...

The tables are overlapping slightly (which I actually like)

This is just a part of my screen to keep size down, I actually had 12 tables up on one monitor.

Last edited by jonwies; 12-14-2009 at 12:00 AM.

Quote

12-14-2009 , 04:21 AM

#62

Max1mums

old hand

Join Date: Aug 2009 Posts: 1,700

Try disabling "drag and drop" function in preferences menu to make buttons work.

Quote

12-14-2009 , 12:12 PM

#63

jonwies

old hand

Join Date: Jan 2009 Posts: 1,245

Still no go, can't click anything

Edit: It's something to do with it's auto-resizing, since on the join waiting list button or any action buttons you can click on the very bottom part of it and it will work. So it seems the real button is offset from where the image of it is, or something...

I can't get any of the top buttons to work at all though

Same with the seats when I try to sit down, I have to click a little bit below them

Last edited by jonwies; 12-14-2009 at 12:40 PM.

Quote

12-14-2009 , 12:43 PM

#64

jonwies

old hand

Join Date: Jan 2009 Posts: 1,245

Trouble with the slider too. The text box for bet size works fine, but again if I try to click the slider I get nothing. I double clicked on it and it brought up the note-taking window for the player seated right above it, so the whole thing is definitely offset somehow.

Quote

12-14-2009 , 12:59 PM

#65

Max1mums

old hand

Join Date: Aug 2009 Posts: 1,700

If you can't click those buttons even if you close the script then that might be the case, i'll try to check it out.

Quote

12-14-2009 , 02:06 PM

#66

jonwies

old hand

Join Date: Jan 2009 Posts: 1,245

Quote:

Originally Posted by Max1mums

If you can't click those buttons even if you close the script

Confirmed, behaves the same after script is closed.

Thanks for the help BTW

Quote

12-15-2009 , 06:06 AM

#67

Max1mums

old hand

Join Date: Aug 2009 Posts: 1,700

Ok, Roland pointed me out that there is simpler way to make it work under Vista/W7 (disabling glass frame), so here is default Roland's script from Overcards with that correction:

Code:

; #### NoTitlebar ####

; AHK version: 1.0.46.09
; date: 5:12 PM Friday, April 06, 2007
; version: 1.04
; author: Roland (roland@overcards.com)

#NoEnv
#NoTrayIcon
#SingleInstance force
#Include %a_scriptDir%
#Include Functions.ahk
#Include *i casinos.ahk
#Include dfc.ahk

SetWorkingDir %a_scriptDir%

If 1 != -i
  Menu, Tray, Icon
  
OnMessage(0x5555, "ExitMsg")

ini = NoTitlebar.ini
IniRead, includeLobby, % ini, Prefs, includeLobby, 0
IniRead, dragNdrop, % ini, Prefs, dragNdrop, 1
IniRead, noBorder, % ini, Prefs, noBorder, 0
IniRead, version, % ini, Prefs, version

Loop, Casinos\*.ahk
  casinos:=addToList(casinos, StrRep(a_loopFileName, ".ahk"))

Menu, Tray, NoStandard
Menu, Tray, Add, &Help, Help
Menu, Tray, Default, &Help
Menu, Tray, Add 
Menu, Tray, Add, &About, About 
Menu, Tray, Add
Menu, Tray, Add, &Preferences, Prefs
Menu, Tray, Add
Menu, Tray, Add, Plug-&In..., PlugIn
Menu, Tray, Add
Menu, Tray, Add, E&xit, Exit
Menu, Tray, Tip, NoTitlebar v%version%

If ( dragNdrop )
  Hotkey, ~LButton, DragNDrop

SetTimer, timer, 500
return

; ## end of auto-execute section ##

; ## timer ##

Timer:
tables := tables() 
Loop, Parse, tables, `,
  { If ( a_loopfield="" )
      continue
    WinGetPos,,, w,, ahk_id%a_loopfield%
    If ( w!=wPrev%a_loopfield% ) {
        WinWaitStatic(a_loopfield, 200)
        Cut(a_loopfield)
      }
    wPrev%a_loopfield% := w
  }
return

; ## cut ##

Cut(win) {
global caption,noBorder
WinGetPos,,, w, h, ahk_id%win%
WinGet, style, style, ahk_id%win%
code:=( style & 0x40000 ) ? 32 : 7
SysGet, border, % code
SysGet, caption, 4
b:=( noBorder ? border : 0 )
c:=dfc(caption . casino(win))
c:=caption!="" ? c : caption
c:=( noBorder ? caption+border : caption )
xx:=w-b, yy:=h-b
if A_OSVersion = WIN_VISTA
    DllCall("dwmapi\DwmSetWindowAttribute","uint",win,"uint",2,"int*",1,"uint",4)
;This sets the DWMWA_NCRENDERING_POLICY attribute to DWMNCRP_DISABLED. To reset it (i.e. from +#Esc), set it back to DWMNCRP_USEWINDOWSTYLE:
;if A_OSVersion = WIN_VISTA
;   DllCall("dwmapi\DwmSetWindowAttribute","uint",WinExist("A"),"uint",2,"int*",0,"uint",4)

WinSet, Region
  , %b%-%c% %xx%-%c% %xx%-%yy% %b%-%yy% %b%-%c%
  , ahk_id%win%
}

; ## tables ##

tables() {
global casinos, includeLobby
Loop, Parse, casinos, `,
  { lobby := dfc("lobby" . a_loopfield)
    If ! lobby
      continue
    theseTables:=dfc("tables" . a_loopfield, lobby)
    If ( theseTables="" )
      continue
    tables := addToList(tables, theseTables)
    If ( includeLobby )
      tables := addToList(tables, lobby)
  }  return tables
}

; ## casino ##

casino(id) {
global casinos
Loop, Parse, casinos, `,
  { lobby := dfc("lobby" . a_loopfield)
    If ! lobby
      continue
    If IsIn(id, dfc("tables" . a_loopfield, lobby))
      return a_loopfield
  }
}

; ## drag&drop ##

DragNDrop:
win := MouseGetWin()
tables := tables() 
If ! IsIn(win, tables)
  return
MouseGetPos,, y
If ( y > 60 )
  return
WinExist("a")
PostMessage, 0xA1, 2
return

; ## Prefs ##

Prefs:
Gui, +toolwindow
Gui, Margin, 5, 5
Gui, Font,, Comic Sans MS
Gui, Add, Checkbox, vincludeLobby checked%includeLobby%, &Include Lobby
Gui, Add, Checkbox, vdragNdrop checked%dragNdrop%, &Enable drag&&drop
Gui, Add, Checkbox, vnoBorder checked%noBorder%, &Strip border completely
Gui, Add, Button, default section h20, Submit
Gui, Add, Button, ys h20, &Cancel
Gui, Show,, Preferences
return

ButtonSubmit:
Gui, Submit
IniWrite, % includeLobby, % ini, Prefs, includeLobby 
IniWrite, % dragNdrop, % ini, Prefs, dragNdrop
IniWrite, % noBorder, % ini, Prefs, noBorder
Reload
return

GuiClose:
GuiEscape:
ButtonCancel:
Gui destroy
return 

; ## tray menu ##

Help:
Run http://www.overcards.com/wiki/moin.cgi/NoTitlebar
return

About:
TrayTip
  , NoTitlebarStars v%version%, Author: Roland`nE-mail: roland@overcards.com
  ,, 1
return

PlugIn:
RunWait PlugIn.ahk
Run Start.ahk

Exit:
exitApp

Last edited by Max1mums; 12-15-2009 at 06:17 AM.

Quote

12-15-2009 , 02:12 PM

#68

guiyom

centurion

Join Date: Jan 2008 Posts: 108

hey thanks, this help me a lot.

Quote

12-15-2009 , 09:27 PM

#69

Max1mums

old hand

Join Date: Aug 2009 Posts: 1,700

Restore function added, enhanced drag&drop added (works with ctrl pressed down), a little bit more pixels removed at the top of the table with just borders. Rate it's work please so that i could upload this version to Overcards.

Code:

; #### NoTitlebar ####

; AHK version: 1.0.48.05
; date: 4:05 PM Wednesday, December 16, 2009
; version: 1.05
; author: Roland (roland@overcards.com)

#NoEnv
#NoTrayIcon
#SingleInstance force
#Include %a_scriptDir%
#Include Functions.ahk
#Include *i casinos.ahk
#Include dfc.ahk

SetWorkingDir %a_scriptDir%

If 1 != -i
  Menu, Tray, Icon
  
OnMessage(0x5555, "ExitMsg")

ini = NoTitlebar.ini
IniRead, includeLobby, % ini, Prefs, includeLobby, 0
IniRead, dragNdrop, % ini, Prefs, dragNdrop, 1
IniRead, noBorder, % ini, Prefs, noBorder, 0
IniRead, restore, % ini, Prefs, restore, 0
IniRead, version, % ini, Prefs, version

Loop, Casinos\*.ahk
  casinos:=addToList(casinos, StrRep(a_loopFileName, ".ahk"))

Menu, Tray, NoStandard
Menu, Tray, Add, &Help, Help
Menu, Tray, Default, &Help
Menu, Tray, Add 
Menu, Tray, Add, &About, About 
Menu, Tray, Add
Menu, Tray, Add, &Preferences, Prefs
Menu, Tray, Add
Menu, Tray, Add, Plug-&In..., PlugIn
Menu, Tray, Add
Menu, Tray, Add, E&xit, Exit
Menu, Tray, Tip, NoTitlebar v%version%

If ( dragNdrop )
  Hotkey, ~LButton, DragNDrop

SetTimer, timer, 300
return

; ## end of auto-execute section ##

; ## timer ##

Timer:
tables := tables() 
Loop, Parse, tables, `,
  { If ( a_loopfield="" )
      continue
    WinGetPos,,, w,, ahk_id%a_loopfield%
    If ( w!=wPrev%a_loopfield% ) {
        WinWaitStatic(a_loopfield, 200)
        Cut(a_loopfield)
      }
    wPrev%a_loopfield% := w
  }
return

; ## cut ##

Cut(win) {
global caption,noBorder,restore
WinGetPos,x,y, w, h, ahk_id%win%
WinGet, style, style, ahk_id%win%
code:=( style & 0x40000 ) ? 32 : 7
SysGet, border, % code
SysGet, caption, 4
b:=( noBorder ? border : 0 )
c:=dfc(caption . casino(win))
c:=caption!="" ? c : caption
c:=( noBorder ? caption+border : caption )

if A_OSVersion = WIN_VISTA
if !restore
;This sets the DWMWA_NCRENDERING_POLICY attribute to DWMNCRP_DISABLED. To reset it (i.e. from +#Esc), set it back to DWMNCRP_USEWINDOWSTYLE:
DllCall("dwmapi\DwmSetWindowAttribute","uint",win,"uint",2,"int*",1,"uint",4)

if restore
{
if A_OSVersion = WIN_VISTA
DllCall("dwmapi\DwmSetWindowAttribute","uint",win,"uint",2,"int*",0,"uint",4)
b:=0
c:=0
}

xx:=w-b, yy:=h-b
if !noborder
if !restore
c:=border+c
WinSet, Region
  , %b%-%c% %xx%-%c% %xx%-%yy% %b%-%yy% %b%-%c%
  , ahk_id%win%
}
; ## tables ##

tables() {
global casinos, includeLobby
Loop, Parse, casinos, `,
  { lobby := dfc("lobby" . a_loopfield)
    If ! lobby
      continue
    theseTables:=dfc("tables" . a_loopfield, lobby)
    If ( theseTables="" )
      continue
    tables := addToList(tables, theseTables)
    If ( includeLobby )
      tables := addToList(tables, lobby)
  }  return tables
}

; ## casino ##

casino(id) {
global casinos
Loop, Parse, casinos, `,
  { lobby := dfc("lobby" . a_loopfield)
    If ! lobby
      continue
    If IsIn(id, dfc("tables" . a_loopfield, lobby))
      return a_loopfield
  }
}

; ## drag&drop ##

DragNDrop:
win := MouseGetWin()
tables := tables() 
If ! IsIn(win, tables)
  return
MouseGetPos,, y
If ( y > 60 )
  return
WinExist("a")
PostMessage, 0xA1, 2
return

; ## Prefs ##

Prefs:
Gui, +toolwindow
Gui, Margin, 5, 5
Gui, Font,, Comic Sans MS
Gui, Add, Checkbox, vincludeLobby checked%includeLobby%, &Include Lobby
Gui, Add, Checkbox, vdragNdrop checked%dragNdrop%, &Enable drag&&drop
Gui, Add, Checkbox, vnoBorder checked%noBorder%, &Strip border completely
Gui, Add, Checkbox, vrestore checked%restore%, &restore borders and caption
Gui, Add, Button, default section h20, Submit
Gui, Add, Button, ys h20, &Cancel
Gui, Show,, Preferences
return

ButtonSubmit:
Gui, Submit
IniWrite, % includeLobby, % ini, Prefs, includeLobby 
IniWrite, % dragNdrop, % ini, Prefs, dragNdrop
IniWrite, % noBorder, % ini, Prefs, noBorder
IniWrite, % restore, % ini, Prefs, restore
Reload
return

GuiClose:
GuiEscape:
ButtonCancel:
Gui destroy
return 

; ## tray menu ##

Help:
Run http://www.overcards.com/wiki/moin.cgi/NoTitlebar
return

About:
TrayTip
  , NoTitlebarStars v%version%, Author: Roland`nE-mail: roland@overcards.com
  ,, 1
return

PlugIn:
RunWait PlugIn.ahk
Run Start.ahk

Exit:
exitApp

CTRL & LButton::
CoordMode, Mouse  ; Switch to screen/absolute coordinates.
MouseGetPos, EWD_MouseStartX, EWD_MouseStartY, EWD_MouseWin
WinGetPos, EWD_OriginalPosX, EWD_OriginalPosY,,, ahk_id %EWD_MouseWin%
SetTimer, EWD_WatchMouse, 10 ; Track the mouse as the user drags it.
return

EWD_WatchMouse:
GetKeyState, EWD_LButtonState, LButton, P
if EWD_LButtonState = U  ; Button has been released, so drag is complete.
{
   SetTimer, EWD_WatchMouse, off
   return
}
GetKeyState, EWD_EscapeState, Escape, P
if EWD_EscapeState = D  ; Escape has been pressed, so drag is cancelled.
{
   SetTimer, EWD_WatchMouse, off
   WinMove, ahk_id %EWD_MouseWin%,, %EWD_OriginalPosX%, %EWD_OriginalPosY%
   Return
}
; Otherwise, reposition the window to match the change in mouse coordinates
; caused by the user having dragged the mouse:
CoordMode, Mouse
MouseGetPos, EWD_MouseX, EWD_MouseY
EWD_DeltaX = %EWD_MouseX%
EWD_DeltaX -= %EWD_MouseStartX%
EWD_DeltaY = %EWD_MouseY%
EWD_DeltaY -= %EWD_MouseStartY%
EWD_MouseStartX = %EWD_MouseX%  ; Update for the next timer call to this subroutine.
EWD_MouseStartY = %EWD_MouseY%
WinGetPos, EWD_WinX, EWD_WinY,,, ahk_id %EWD_MouseWin%
EWD_WinX += %EWD_DeltaX%
EWD_WinY += %EWD_DeltaY%
SetWinDelay, -1   ; Makes the below move faster/smoother.
WinMove, ahk_id %EWD_MouseWin%,, %EWD_WinX%, %EWD_WinY%
return

Quote

12-16-2009 , 01:48 AM

#70

pokor playar

centurion

Join Date: Apr 2009 Posts: 180

Max1mums, I really appreciate the the work your putting into this. Thank you

Quote

12-17-2009 , 11:57 AM

#71

Jtringer

veteran

Join Date: Jan 2009 Posts: 2,541

will this work with IPoker/?

Quote

12-17-2009 , 12:47 PM

#72

Max1mums

old hand

Join Date: Aug 2009 Posts: 1,700

Notitlebar plugins are usually custom for every pokerroom but these two might work for all ipoker and prima sites:
(run start.ahk, choose Plug-in from script menu, Casino name is line above of code, paste code to edit box.)

ipoker

Code:

lobbyipoker() {
SetTitleMatchMode 2
WinGet, id, id, Tables: ahk_class PTIODEVICE
return id
}

tablesipoker(lobby) {
SetTitleMatchMode 2
WinGet, pid, pid, ahk_id%lobby%
WinGet, list, list, / ahk_class PTIODEVICE
Loop % list 
 tables := list%a_index%!=lobby 
    ? addToList(tables, list%a_index%) 
    : tables
return tables
}

prima

Code:

lobbyprima() {
SetTitleMatchMode 1
WinGet, id, id, ahk_class GFX_INT_DLG_WINDOW_MAIN_PrimaPokerNetwork
return id
}

tablesprima(lobby) {
SetTitleMatchMode 2
WinGet, pid, pid, ahk_id%lobby%
WinGet, list, list,ahk_class POPUP_INT_DLG_WINDOW
Loop % list 
 tables := list%a_index%!=lobby 
    ? addToList(tables, list%a_index%) 
    : tables
return tables
}

Quote

12-17-2009 , 03:42 PM

#73

Jtringer

veteran

Join Date: Jan 2009 Posts: 2,541

Quote:

Originally Posted by Max1mums

Code:

lobbyipoker() {
SetTitleMatchMode 2
WinGet, id, id, Tables: ahk_class PTIODEVICE
return id
}

tablesipoker(lobby) {
SetTitleMatchMode 2
WinGet, pid, pid, ahk_id%lobby%
WinGet, list, list, / ahk_class PTIODEVICE
Loop % list 
 tables := list%a_index%!=lobby 
    ? addToList(tables, list%a_index%) 
    : tables
return tables
}

prima

Code:

lobbyprima() {
SetTitleMatchMode 1
WinGet, id, id, ahk_class GFX_INT_DLG_WINDOW_MAIN_PrimaPokerNetwork
return id
}

tablesprima(lobby) {
SetTitleMatchMode 2
WinGet, pid, pid, ahk_id%lobby%
WinGet, list, list,ahk_class POPUP_INT_DLG_WINDOW
Loop % list 
 tables := list%a_index%!=lobby 
    ? addToList(tables, list%a_index%) 
    : tables
return tables
}

if this works i love you

Quote

12-17-2009 , 05:33 PM

#74

TomoDaK

Pooh-Bah

Join Date: Feb 2008 Posts: 5,837

Thanks a ton for all the updates, just tried the recent version works much better no goofy ass graphical corruption.

Quote

12-17-2009 , 10:24 PM

#75

Jtringer

veteran

Join Date: Jan 2009 Posts: 2,541

k, so i know like nothing about programming and am having major troubles with this.

So far I have:
-put the 'somecasino' file into the casinos folder and renamed it ipoker(and replaced all the somecasino terms inside the file with 'Betfred')
-Then I made a blank AHK file called Betfred and pasted the code you gave me above

I cant figure out what to do next, and its giving me 'calling nonexistant function' or w/e,

any help?

Quote

Page 3 of 6

First

1 2 3 4 5 6

Last

Post Reply Subscribe

...

Page 3 of 6

First

1 2 3 4 5 6

Last