Jackpot Poker PT4 Tournament Summary Generator - Page 3 - Winning Poker Network -- Two Plus Two Poker Forums

Two Plus Two Forums Archived Forums Internet Poker Winning Poker Network

Jackpot Poker PT4 Tournament Summary Generator

...

Page 3 of 4

1 2 3 4

Page 3 of 4

1 2 3 4

05-17-2016 , 06:30 PM

#51

Max Cut

Guest

Posts: n/a

Quote:

Originally Posted by StructureK

Can this be used to create summaries for MTTS as well?

Possibly with some modifications. I'll have a look when I get some time

06-03-2016 , 12:24 AM

#52

GutPunch

veteran

Join Date: Feb 2005 Posts: 3,198

what does the update PT4/HM2 do?

06-04-2016 , 11:01 AM

#53

Max Cut

Guest

Posts: n/a

Quote:

Originally Posted by GutPunch

what does the update PT4/HM2 do?

Sorry, busy week and not 100% clear on the question. Perhaps you're referring to the PT4/HM2 update feature of the Jackpot Counter? If so, it updates the $ winnings in PT4/HM2. The program in this thread creates tournament summaries that can be imported into PT4 for the same purpose of updating the $ winnings.

07-11-2016 , 07:28 PM

#54

ACR Police

newbie

Join Date: May 2016 Posts: 19

Quote:

Originally Posted by Max Cut

Possibly with some modifications. I'll have a look when I get some time

Is there any progress on making this work on mtts? Would be amazing if you got it to work on them as PT4 still doesn't get info from them.

07-12-2016 , 10:32 AM

#55

Max Cut

Guest

Posts: n/a

Quote:

Originally Posted by ACR Police

Is there any progress on making this work on mtts? Would be amazing if you got it to work on them as PT4 still doesn't get info from them.

Thanks for the reminder. If you (or anyone) could copy and paste an example MTT line from the report, that would be helpful. (For Jackpot Poker they look like below.)

Code:

2705315 Hold'em $2.00 Jackpot Poker $1.88 0.00 0.00 0.00 $0.09 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 5/30/2015 6:47:07 PM 5/30/2015 6:47:19 PM 5/30/2015 6:53:16 PM 00:05:57 
2705353 Hold'em $2.00 Jackpot Poker $1.88 0.00 0.00 0.00 $0.09 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $4.00 0.00 0.00 0.00 5/30/2015 6:52:00 PM 5/30/2015 6:52:12 PM 5/30/2015 6:57:38 PM 00:05:26 
2705388 Hold'em $2.00 Jackpot Poker $1.88 0.00 0.00 0.00 $0.09 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $12.00 0.00 0.00 0.00 5/30/2015 6:55:53 PM 5/30/2015 6:56:06 PM 5/30/2015 7:04:49 PM 00:08:43 
2705475 Hold'em $2.00 Jackpot Poker $1.88 0.00 0.00 0.00 $0.09 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 $0.00 0.00 0.00 0.00 5/30/2015 7:07:38 PM 5/30/2015 7:07:49 PM 5/30/2015 7:11:31 PM 00:03:42

07-12-2016 , 01:25 PM

#56

bbuhbowler

journeyman

Join Date: Sep 2015 Posts: 290

keep getting "0 tournament summaries written to folder"

does it matter where i create the folder or .txt file? I used notepad for the text file. right now they are in my documents folder. feel like I followed the instructions to a tee, although i'm sure its something simple i'm doing wrong. tried loading 200 and just 5 as well.

Either way the work you've put into this is awesome, Much Appreciated!

07-12-2016 , 01:40 PM

#57

Max Cut

Guest

Posts: n/a

Quote:

Originally Posted by bbuhbowler

Thanks for the report. I just gave it a test and I'm getting the same result. There was probably a small change to the report format. I will investigate and post a fix as soon as I can.

07-12-2016 , 02:18 PM

#58

Max Cut

Guest

Posts: n/a

Updated for change in the WPN tournament report. (Some spaces are now tabs in the report when copy-pasted.)

Executable:
www.dropbox.com/s/lw0pdy33hz9uhq2/JackpotTS.exe?dl=0

AHK source:
www.dropbox.com/s/w83d2sayeuczdrb/JackpotTS.ahk?dl=0

AHK source:

Code:

;;;
;;; Jackpot Poker PT4 Tournament Summary Generator
;;;
;;; Creates tournament summaries for WPN Jackpot Poker tournaments that 
;;; can be imported to PokerTracker 4 so that winnings are accurately recorded.
;;;
;;; Author: 2+2 user Max Cut
;;; June 2015
;;; Most recent update: July 12, 2016
;;;

#SingleInstance Force
#NoEnv
#Persistent


;;;
;;; Build the GUI
;;;
Menu, HelpMenu, Add, &Help, Help
Menu, HelpMenu, Add, &2+2 thread, 2p2Thread
Menu, HelpMenu, Add, &About, About
Menu, MyMenuBar, Add, &Help, :HelpMenu

Gui, Menu, MyMenuBar
Gui, Add, Text, x18 y13 w80, Screen Name
Gui, Add, Button, x10 y40 w80 h22 gResultsSelect, Results File
Gui, Add, Button, x10 y70 w80 h22 gOutputSelect, Output Folder
Gui, Add, Checkbox, x315 y39 w55  vCashesOnly Checked, Cashes Only
Gui, Add, Checkbox, x315 y75 w55  vAllFirst, All 1st
Gui, Add, Edit, x95 y10 w130 Left vScreenname
Gui, Add, Edit, x95 y40 w215 Left vResultsFile
Gui, Add, Edit, x95 y70 w215 Left vOutputFolder
Gui, Add, Progress, x230 y9 w140 h22 -Smooth Disabled
Gui, Font, c008800 s10
Gui, Add, Text, x230 w140 y9  h22 Center 0x200 BackgroundTrans  gGenerateSummaries, Generate Summaries
FullGui := WinExist()
Gui, Show, h100 w 380, Jackpot Poker TS Generator
Gui, Submit, NoHide
return



;;;
;;; Help dialog.
;;;
Help:
helpText = 
( LTrim
	Jakpot Poker Tournament summary Generator
	
	Creates PokerTracker 4 tournament summaries for WPN Jackpot Poker tournaments so that winnings are acurately recorded.
	
	
	Steps for use:
		
		1) Navigate in poker client to "My Account" --> "Transactions".
		
		2) From the "Poker Statistics" options, select "Tournaments" (not to be confused with "Tournament History").
		
		3) Select desired date range and specify number of records per page; click the "Submit" button. 
				
		4) Copy and paste the entire tournament results into a text file (no need for the colum headers or totals at the bottom).
		
		5) Enter screen name.
		
		6) Enter/select the results file (created in step 4).
		
		7) Enter/select an output folder for tournament summaries.
		
		8) If you wish it to write a summary for all games, uncheck "Cashes Only".
		
		9) If you wish it to always write "1st place" rather than blank, check "All 1st".
		
		9) Push Generate Summaries button.
		
		10) In the PokerTracker client, import the tournament summaries by navigating to "Play Poker" --> "Get Hands from Disk" --> "Select Directory" to choose the output folder.
		
		
		2+2 thread (link available in help menu) :
		http://forumserver.twoplustwo.com/218/winning-poker-network/jackpot-poker-pt4-tournament-summary-generator-1536354/
)
MsgBox,, Jackpot Poker TS generator: HELP, %helpText%
return



;;;
;;; Link to 2+2 thread
;;;
2p2Thread:
	Run http://forumserver.twoplustwo.com/218/winning-poker-network/jackpot-poker-pt4-tournament-summary-generator-1536354/
return



;;;
;;; About dialog.
;;;
About:
aboutText = 
( LTrim
	Jackpot Poker TS Generator is free from 2+2 member Max Cut.
)
MsgBox,, Jackpot Poker TS generator: ABOUT, %aboutText%
return



;;;
;;; Dialog for selecting results file.
;;;
ResultsSelect:
FileSelectFile, SelectedFile, 3, , Select results file..., Text Documents (*.txt)
If SelectedFile = 
{
	if ResultsFile =
	{
		MsgBox,, Jackpot Poker TS generator: ERROR, Please select a results file...
	}
}
else
{
	ResultsFile := SelectedFile
	GuiControl, , ResultsFile, %SelectedFile%
}
return



;;;
;;; Dialog for selecting output folder
;;;
OutputSelect:
FileSelectFolder, SelectedFolder,, 3, Select output folder...
If SelectedFolder = 
{
	if OutputFolder =
	{
		MsgBox,, Jackpot Poker TS generator: ERROR, Please select a folder for the tournament summaries...
	}
}
else
{
	OutputFolder := SelectedFolder
	GuiControl, , OutputFolder, %SelectedFolder%
}
return



;;;
;;; Generate PT4 tournament summaries from 
;;; results file and write them to output folder
;;;
GenerateSummaries:
Gui, Submit, NoHide

;;; Basic error chaecking
If ScreenName = 
{
	MsgBox,, Jackpot Poker TS generator: ERROR, Please enter a screen name...
	return
}
If ResultsFile = 
{
	MsgBox,, Jackpot Poker TS generator: ERROR, Please select a results file...
	return
}
FileRead, results, %ResultsFile%
If ErrorLevel
{ 
	MsgBox,, Jackpot Poker TS generator: ERROR, Error reading results file: `"%ResultsFile%`".`n`nPlease select a results file...
	return
}
IfNotExist, %OutputFolder% 
{
	MsgBox,, Jackpot Poker TS generator: ERROR, Folder `"%OutputFolder%`" not found.`n`nPlease select a folder for the tournament summaries...
	return
}
	
;;; Number of TS written.
TScount := 0

Loop, Parse, results, `n
{
	;;; line will hold a line from the results file.
	;;; line4 will hold the game type -- looking for Jackpot games.
	line4 =
	StringSplit, line, A_LoopField, %A_Space%%A_Tab%
	
	winnings := SubStr(line22, 2)
	
	;;; Only generating TS for Jackpot Poker...
	IfNotInString, line4, Jackpot
	{
		;;; or WSOJ.
		IfNotInString, line5, Jackpot
		continue
	}

	;;; Only need to make TS when there are winnings.
	if  (0 >= winnings)
	{
		if (CashesOnly) {
			continue
		}
	}
	
	StringSplit, dateParts, line29, /
	SetFormat, FloatFast, 02
	startyear := dateParts3
	startmonth := dateParts1 + 0.0
	startday := dateParts2 + 0.0

	StringSplit, dateParts, line32, /
	SetFormat, FloatFast, 02
	endyear := dateParts3
	endmonth := dateParts1 + 0.0
	endday := dateParts2 + 0.0
	tsdate = %endyear%%endmonth%%endday%	
	
	;;; We leave finish position blank sine PT4 already figured it out from 
	;;; the hand history and there is no way to always tell from the report data.
	;;; Seems to import fine this way.
	finishpos =
	if (AllFirst) {
		finishpos = 1
	}
	
	;;; tstext is the tournament summary text.
	tstext1 =
	tstext1 = 
	( LTrim
		PokerTracker 4 Tournament Summary
		Site: Yatahay Network
		Game: %line2%
		Tournament #: %line1%
		Started: %startyear%/%startmonth%/%startday%
		Finished: %endyear%/%endmonth%/%endday%
		
	)
	
	;;; Account for Sit&Crush fee which is not reported as rake
	SetFormat, FloatFast, 0.2
	StringTrimLeft, fee, line10, 1
	adjFee := fee / 0.75
	
	;;; $3 WSOJ get rounded up apparently.
	IfInString, line4, WSOP
	{
		IfInString, line6, $2.82
		{
			adjFee := 0.18
		}
	}

	tstext2 =
	tstext2 = 
	( LTrim
		Buyin: %line6%
		Fee: $%adjFee%
		Table Type: STT (3 max) Hyper-Turbo SNG LOTTERY
		Tourney Type: No Limit
		Players: 3
		
		Place: %finishpos%, Player: %ScreenName%, Won: %line22%,
	)
	
	;;; tspath is the path of the output tournament summary file to create.
	tspath = %OutputFolder%\T#%line1% - %line6% + $%adjFee% - %tsdate% - Summary.txt

	;;; Overwrite existing summary.
	IfExist, %tspath%
	{
		FileDelete, %tspath%
	}
	
	;;; Write the tournament summary.
	FileAppend, %tstext1%%tstext2%, %tspath%
	if (not ErrorLevel)
	{
		TScount++
	}
}

;;; Report number of tournament summaries generated.
MsgBox, %TScount%  tournament summaries written to folder %OutputFolder%
return



;;; Shut it down!
GuiClose:
ExitApp
return

07-12-2016 , 03:18 PM

#59

bbuhbowler

journeyman

Join Date: Sep 2015 Posts: 290

Thanks Max Cut, worked great. you da man!

07-14-2016 , 11:04 PM

#60

ACR Police

newbie

Join Date: May 2016 Posts: 19

here is what the mtt data looks like. let me know if you need anything else

Code:

5509090	Hold'em	$25,000 GTD	$20.00	0.00	0.00	0.00	$2.00	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	7/10/2016 12:19:23 PM	7/10/2016 2:00:00 PM	7/10/2016 7:23:37 PM	05:23:37
5509211	Hold'em	$1,500 GTD	$3.00	0.00	0.00	0.00	$0.30	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	7/10/2016 12:19:28 PM	7/10/2016 2:00:00 PM	7/10/2016 4:36:44 PM	02:36:44
5517370	Hold'em	$25 GTD - On Demand	$0.50	0.00	0.00	0.00	$0.05	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	$1.44	0.00	0.00	0.00	7/9/2016 9:37:10 PM	7/9/2016 10:09:55 PM	7/10/2016 12:10:07 AM	02:00:12

07-15-2016 , 12:22 PM

#61

glutenfree

old hand

Join Date: Sep 2005 Posts: 1,766

Quote:

Originally Posted by ACR Police

here is what the mtt data looks like. let me know if you need anything else

Code:

5509090	Hold'em	$25,000 GTD	$20.00	0.00	0.00	0.00	$2.00	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	7/10/2016 12:19:23 PM	7/10/2016 2:00:00 PM	7/10/2016 7:23:37 PM	05:23:37
5509211	Hold'em	$1,500 GTD	$3.00	0.00	0.00	0.00	$0.30	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	7/10/2016 12:19:28 PM	7/10/2016 2:00:00 PM	7/10/2016 4:36:44 PM	02:36:44
5517370	Hold'em	$25 GTD - On Demand	$0.50	0.00	0.00	0.00	$0.05	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	$0.00	0.00	0.00	0.00	$1.44	0.00	0.00	0.00	7/9/2016 9:37:10 PM	7/9/2016 10:09:55 PM	7/10/2016 12:10:07 AM	02:00:12

The problem with the MTT summary is that the total entries and finish position aren't provided, unlike JPP where the entries is always 3 and the finish position is easily determined by the HH. I have been asking for a long time for a tourney summary to be written to file or available on request but so far nothing.

At any rate for simply tracking results and ROI the Max Cut summary would be great! I think if you care about field size and finish position you'd still have to do that part manually.

07-15-2016 , 01:23 PM

#62

Max Cut

Guest

Posts: n/a

Thanks for the sample. Looks like it should be doable, but only for updating winnings as glutenfree pointed out.

07-22-2016 , 12:35 PM

#63

Max Cut

Guest

Posts: n/a

This is a test version for MTTs and possibly SNGs. (Continue with JackpotTS for Jackpot Poker.)

Executable:
www.dropbox.com/s/by8obkil7x1xczo/WPN_TS.exe?dl=0

AHK source:
www.dropbox.com/s/ud6i1hsse4baj79/WPN_TS.ahk?dl=0

AHK source:

Code:

;;;
;;; WPN PT4 Tournament Summary Generator
;;;
;;; Creates tournament summaries for WPN tournaments that can be
;;; imported to PokerTracker 4 so that winnings are accurately recorded.
;;;
;;; Author: 2+2 user Max Cut
;;; June 2015
;;; Most recent update: July 22, 2016
;;;

#SingleInstance Force
#NoEnv
#Persistent


;;;
;;; Build the GUI
;;;
Menu, HelpMenu, Add, &Help, Help
Menu, HelpMenu, Add, &2+2 thread, 2p2Thread
Menu, HelpMenu, Add, &About, About
Menu, MyMenuBar, Add, &Help, :HelpMenu

Gui, Menu, MyMenuBar
Gui, Add, Text, x18 y13 w80, Screen Name
Gui, Add, Button, x10 y40 w80 h22 gResultsSelect, Results File
Gui, Add, Button, x10 y70 w80 h22 gOutputSelect, Output Folder
Gui, Add, Checkbox, x315 y37 w55  vCashesOnly Checked, Cashes Only
Gui, Add, Checkbox, x315 y69 w60  vAdjTheFee, Adj Fee for SNC
Gui, Add, Edit, x95 y10 w130 Left vScreenname
Gui, Add, Edit, x95 y40 w215 Left vResultsFile
Gui, Add, Edit, x95 y70 w215 Left vOutputFolder
Gui, Add, Progress, x230 y9 w140 h22 -Smooth Disabled
Gui, Font, c008800 s10
Gui, Add, Text, x230 w140 y9  h22 Center 0x200 BackgroundTrans  gGenerateSummaries, Generate Summaries
FullGui := WinExist()
Gui, Show, h100 w 380, WPN Tournament Summary Generator
Gui, Submit, NoHide
return



;;;
;;; Help dialog.
;;;
Help:
helpText = 
( LTrim
	WPN Tournament summary Generator
	
	Creates PokerTracker 4 tournament summaries for WPN tournaments so that winnings are acurately recorded.
	
	
	Steps for use:
		
		1) Navigate in poker client to "My Account" --> "Transactions".
		
		2) From the "Poker Statistics" options, select "Tournaments" (not to be confused with "Tournament History").
		
		3) Select desired date range and specify number of records per page; click the "Submit" button. 
				
		4) Copy and paste the entire tournament results into a text file (no need for the colum headers or totals at the bottom).
		
		5) Enter screen name.
		
		6) Enter/select the results file (created in step 4).
		
		7) Enter/select an output folder for tournament summaries.
		
		8) If you wish it to write a summary for all games, uncheck "Cashes Only".
		
		9) If tournament awards Sit&Crush points, select "Adj Fee for SNC".
		
		9) Push Generate Summaries button.
		
		10) In the PokerTracker client, import the tournament summaries by navigating to "Play Poker" --> "Get Hands from Disk" --> "Select Directory" to choose the output folder.
		
		
		2+2 thread (link available in help menu) :
		http://forumserver.twoplustwo.com/218/winning-poker-network/jackpot-poker-pt4-tournament-summary-generator-1536354/
)
MsgBox,, WPN TS generator: HELP, %helpText%
return



;;;
;;; Link to 2+2 thread
;;;
2p2Thread:
	Run http://forumserver.twoplustwo.com/218/winning-poker-network/jackpot-poker-pt4-tournament-summary-generator-1536354/
return



;;;
;;; About dialog.
;;;
About:
aboutText = 
( LTrim
	WPN TS Generator is free from 2+2 member Max Cut.
)
MsgBox,, WPN TS generator: ABOUT, %aboutText%
return



;;;
;;; Dialog for selecting results file.
;;;
ResultsSelect:
FileSelectFile, SelectedFile, 3, , Select results file..., Text Documents (*.txt)
If SelectedFile = 
{
	if ResultsFile =
	{
		MsgBox,, WPN TS generator: ERROR, Please select a results file...
	}
}
else
{
	ResultsFile := SelectedFile
	GuiControl, , ResultsFile, %SelectedFile%
}
return



;;;
;;; Dialog for selecting output folder
;;;
OutputSelect:
FileSelectFolder, SelectedFolder,, 3, Select output folder...
If SelectedFolder = 
{
	if OutputFolder =
	{
		MsgBox,, WPN TS generator: ERROR, Please select a folder for the tournament summaries...
	}
}
else
{
	OutputFolder := SelectedFolder
	GuiControl, , OutputFolder, %SelectedFolder%
}
return



;;;
;;; Generate PT4 tournament summaries from 
;;; results file and write them to output folder
;;;
GenerateSummaries:
Gui, Submit, NoHide

;;; Basic error chaecking
If ScreenName = 
{
	MsgBox,, WPN TS generator: ERROR, Please enter a screen name...
	return
}
If ResultsFile = 
{
	MsgBox,, WPN TS generator: ERROR, Please select a results file...
	return
}
FileRead, results, %ResultsFile%
If ErrorLevel
{ 
	MsgBox,, WPN TS generator: ERROR, Error reading results file: `"%ResultsFile%`".`n`nPlease select a results file...
	return
}
IfNotExist, %OutputFolder% 
{
	MsgBox,, WPN TS generator: ERROR, Folder `"%OutputFolder%`" not found.`n`nPlease select a folder for the tournament summaries...
	return
}
	
;;; Number of TS written.
TScount := 0

Loop, Parse, results, `n
{
	;;; line will hold a line from the results file.
	;;; line4 will hold the game type -- looking for Jackpot games.
	line4 =
	StringSplit, line, A_LoopField, %A_Space%%A_Tab%
	if (0 >= line0)
	{
		continue
	}
	
	;;; Report can split into different number of elements depending on 
	;;; the tournament, so we count back from the end, which is consistent.
	winningsIndex := line0 - 13
	winnings := SubStr(line%winningsIndex%, 2)
	
	;;; Only need to make TS when there are winnings.
	if  (0 >= winnings)
	{
		if (CashesOnly) {
			continue
		}
	}
	
	startIndex := line0 - 6
	StringSplit, dateParts, line%startIndex%, /
	SetFormat, FloatFast, 02
	startyear := dateParts3
	startmonth := dateParts1 + 0.0
	startday := dateParts2 + 0.0

	endIndex := line0 - 3
	StringSplit, dateParts, line%endIndex%, /
	SetFormat, FloatFast, 02
	endyear := dateParts3
	endmonth := dateParts1 + 0.0
	endday := dateParts2 + 0.0
	tsdate = %endyear%%endmonth%%endday%	
	
	;;; We leave finish position blank sine PT4 already figured it out from 
	;;; the hand history and there is no way to always tell from the report data.
	;;; Seems to import fine this way.
	finishpos =
	
	;;; tstext is the tournament summary text.
	tstext1 =
	tstext1 = 
	( LTrim
		PokerTracker 4 Tournament Summary
		Site: Yatahay Network
		Game: %line2%
		Tournament #: %line1%
		Started: %startyear%/%startmonth%/%startday%
		Finished: %endyear%/%endmonth%/%endday%
		
	)
	
	buyinIndex := line0 - 29
	buyin := line%buyinIndex%
	feeIndex := line0 - 25
	fee := line%feeIndex%
	StringTrimLeft, fee, fee, 1
	
	;;; Account for Sit&Crush fee which is not reported as rake
	SetFormat, FloatFast, 0.2
	adjFee := fee ;/ 0.75
	if (adjTheFee)
	{
		adjFee /= 0.75
	}
	

	tstext2 =
	tstext2 = 
	( LTrim
		Buyin: %buyin%
		Fee: $%adjFee%		
		Place: %finishpos%, Player: %ScreenName%, Won: %winnings%,
	)
	
	;;; tspath is the path of the output tournament summary file to create.
	tspath = %OutputFolder%\T#%line1% - %buyin% + $%adjFee% - %tsdate% - Summary.txt

	;;; Overwrite existing summary.
	IfExist, %tspath%
	{
		FileDelete, %tspath%
	}
	
	;;; Write the tournament summary.
	FileAppend, %tstext1%%tstext2%, %tspath%
	if (not ErrorLevel)
	{
		TScount++
	}
}

;;; Report number of tournament summaries generated.
MsgBox, %TScount%  tournament summaries written to folder %OutputFolder%
return



;;; Shut it down!
GuiClose:
ExitApp
return

07-22-2016 , 02:33 PM

#64

bbuhbowler

journeyman

Join Date: Sep 2015 Posts: 290

didn't have a huge sample to work with, but looks like it worked.

Good stuff Max Thanks again!

08-06-2016 , 10:40 PM

#65

ACR Police

newbie

Join Date: May 2016 Posts: 19

I may be doing something wrong but it doesn't appear to be working for me. Here is that i got when the import was complete.

09:38:46 pm: Yatahay Network: Tournament #xxxxxxx:
09:38:46 pm: Warning: Tournament has an invalid start or end time. This site may require hand import prior to summary import.
09:38:47 pm: - Generic summary type retained: MTT
09:38:47 pm: Import complete. No hands or summaries in 1 file were imported. (0 errors, 0 duplicates)

I imported the HH before importing this generated summary so not sure what went wrong.

08-07-2016 , 12:08 PM

#66

Max Cut

Guest

Posts: n/a

ACR Police, have you had success with it on any MTTs? For the one that failed, does the tournament number match exactly in PT4, the WPN report, and the TS?

08-07-2016 , 01:42 PM

#67

ACR Police

newbie

Join Date: May 2016 Posts: 19

Yes, the tourney ID numbers all match. I used the Jackpot summary converter months ago once with success, tried it again about a month ago and wasn't working for me, and now when trying the mtt summary converter i can't get it to work for me either. Let me know what info i can provide to help diagnose what the issue is. Thanks for looking into it, i appreciate it.

08-07-2016 , 06:37 PM

#68

bbuhbowler

journeyman

Join Date: Sep 2015 Posts: 290

working for me

08-07-2016 , 06:44 PM

#69

ACR Police

newbie

Join Date: May 2016 Posts: 19

Quote:

Originally Posted by bbuhbowler

working for me

can you describe the steps you follow? maybe i'm doing something out of order or something

08-08-2016 , 10:17 AM

#70

bbuhbowler

journeyman

Join Date: Sep 2015 Posts: 290

following the steps from post #1, except having a MTT results .txt file and MTT folder. I'm not sure its even necessary to have a different .txt file or folder.

08-09-2016 , 05:29 AM

#71

ACR Police

newbie

Join Date: May 2016 Posts: 19

Hmm... Max cut, what do can I do to diagnose my issue?

08-09-2016 , 09:42 AM

#72

Max Cut

Guest

Posts: n/a

Quote:

Originally Posted by ACR Police

Hmm... Max cut, what do can I do to diagnose my issue?

Try the new version (below). I doubt it makes any difference, but worth a try.

Check the date of a tournament in PT4 and compare it to the WPN report and the generated summary.

Post a sample report line and the TS generated from it (redact as desired).

08-09-2016 , 09:45 AM

#73

Max Cut

Guest

Posts: n/a

*** This is the test version for MTTs and possibly SNGs. (Continue with JackpotTS for Jackpot Poker.)
Added missing "$" to winnings.

Executable:
www.dropbox.com/s/by8obkil7x1xczo/WPN_TS.exe?dl=0

AHK source:
www.dropbox.com/s/ud6i1hsse4baj79/WPN_TS.ahk?dl=0

AHK source:

Code:

;;;
;;; WPN PT4 Tournament Summary Generator
;;;
;;; Creates tournament summaries for WPN tournaments that can be
;;; imported to PokerTracker 4 so that winnings are accurately recorded.
;;;
;;; Author: 2+2 user Max Cut
;;; June 2015
;;; Most recent update: August 9, 2016
;;;

#SingleInstance Force
#NoEnv
#Persistent


;;;
;;; Build the GUI
;;;
Menu, HelpMenu, Add, &Help, Help
Menu, HelpMenu, Add, &2+2 thread, 2p2Thread
Menu, HelpMenu, Add, &About, About
Menu, MyMenuBar, Add, &Help, :HelpMenu

Gui, Menu, MyMenuBar
Gui, Add, Text, x18 y13 w80, Screen Name
Gui, Add, Button, x10 y40 w80 h22 gResultsSelect, Results File
Gui, Add, Button, x10 y70 w80 h22 gOutputSelect, Output Folder
Gui, Add, Checkbox, x315 y37 w55  vCashesOnly Checked, Cashes Only
Gui, Add, Checkbox, x315 y69 w60  vAdjTheFee, Adj Fee for SNC
Gui, Add, Edit, x95 y10 w130 Left vScreenname
Gui, Add, Edit, x95 y40 w215 Left vResultsFile
Gui, Add, Edit, x95 y70 w215 Left vOutputFolder
Gui, Add, Progress, x230 y9 w140 h22 -Smooth Disabled
Gui, Font, c008800 s10
Gui, Add, Text, x230 w140 y9  h22 Center 0x200 BackgroundTrans  gGenerateSummaries, Generate Summaries
FullGui := WinExist()
Gui, Show, h100 w 380, WPN Tournament Summary Generator
Gui, Submit, NoHide
return



;;;
;;; Help dialog.
;;;
Help:
helpText = 
( LTrim
	WPN Tournament summary Generator
	
	Creates PokerTracker 4 tournament summaries for WPN tournaments so that winnings are acurately recorded.
	
	
	Steps for use:
		
		1) Navigate in poker client to "My Account" --> "Transactions".
		
		2) From the "Poker Statistics" options, select "Tournaments" (not to be confused with "Tournament History").
		
		3) Select desired date range and specify number of records per page; click the "Submit" button. 
				
		4) Copy and paste the entire tournament results into a text file (no need for the colum headers or totals at the bottom).
		
		5) Enter screen name.
		
		6) Enter/select the results file (created in step 4).
		
		7) Enter/select an output folder for tournament summaries.
		
		8) If you wish it to write a summary for all games, uncheck "Cashes Only".
		
		9) If tournament awards Sit&Crush points, select "Adj Fee for SNC".
		
		9) Push Generate Summaries button.
		
		10) In the PokerTracker client, import the tournament summaries by navigating to "Play Poker" --> "Get Hands from Disk" --> "Select Directory" to choose the output folder.
		
		
		2+2 thread (link available in help menu) :
		http://forumserver.twoplustwo.com/218/winning-poker-network/jackpot-poker-pt4-tournament-summary-generator-1536354/
)
MsgBox,, WPN TS generator: HELP, %helpText%
return



;;;
;;; Link to 2+2 thread
;;;
2p2Thread:
	Run http://forumserver.twoplustwo.com/218/winning-poker-network/jackpot-poker-pt4-tournament-summary-generator-1536354/
return



;;;
;;; About dialog.
;;;
About:
aboutText = 
( LTrim
	WPN TS Generator is free from 2+2 member Max Cut.
)
MsgBox,, WPN TS generator: ABOUT, %aboutText%
return



;;;
;;; Dialog for selecting results file.
;;;
ResultsSelect:
FileSelectFile, SelectedFile, 3, , Select results file..., Text Documents (*.txt)
If SelectedFile = 
{
	if ResultsFile =
	{
		MsgBox,, WPN TS generator: ERROR, Please select a results file...
	}
}
else
{
	ResultsFile := SelectedFile
	GuiControl, , ResultsFile, %SelectedFile%
}
return



;;;
;;; Dialog for selecting output folder
;;;
OutputSelect:
FileSelectFolder, SelectedFolder,, 3, Select output folder...
If SelectedFolder = 
{
	if OutputFolder =
	{
		MsgBox,, WPN TS generator: ERROR, Please select a folder for the tournament summaries...
	}
}
else
{
	OutputFolder := SelectedFolder
	GuiControl, , OutputFolder, %SelectedFolder%
}
return



;;;
;;; Generate PT4 tournament summaries from 
;;; results file and write them to output folder
;;;
GenerateSummaries:
Gui, Submit, NoHide

;;; Basic error chaecking
If ScreenName = 
{
	MsgBox,, WPN TS generator: ERROR, Please enter a screen name...
	return
}
If ResultsFile = 
{
	MsgBox,, WPN TS generator: ERROR, Please select a results file...
	return
}
FileRead, results, %ResultsFile%
If ErrorLevel
{ 
	MsgBox,, WPN TS generator: ERROR, Error reading results file: `"%ResultsFile%`".`n`nPlease select a results file...
	return
}
IfNotExist, %OutputFolder% 
{
	MsgBox,, WPN TS generator: ERROR, Folder `"%OutputFolder%`" not found.`n`nPlease select a folder for the tournament summaries...
	return
}
	
;;; Number of TS written.
TScount := 0

Loop, Parse, results, `n
{
	;;; line will hold a line from the results file.
	;;; line4 will hold the game type -- looking for Jackpot games.
	line4 =
	StringSplit, line, A_LoopField, %A_Space%%A_Tab%
	if (0 >= line0)
	{
		continue
	}
	
	;;; Report can split into different number of elements depending on 
	;;; the tournament, so we count back from the end, which is consistent.
	winningsIndex := line0 - 13
	winnings := SubStr(line%winningsIndex%, 2)
	
	;;; Only need to make TS when there are winnings.
	if  (0 >= winnings)
	{
		if (CashesOnly) {
			continue
		}
	}
	
	startIndex := line0 - 6
	StringSplit, dateParts, line%startIndex%, /
	SetFormat, FloatFast, 02
	startyear := dateParts3
	startmonth := dateParts1 + 0.0
	startday := dateParts2 + 0.0

	endIndex := line0 - 3
	StringSplit, dateParts, line%endIndex%, /
	SetFormat, FloatFast, 02
	endyear := dateParts3
	endmonth := dateParts1 + 0.0
	endday := dateParts2 + 0.0
	tsdate = %endyear%%endmonth%%endday%	
	
	;;; We leave finish position blank sine PT4 already figured it out from 
	;;; the hand history and there is no way to always tell from the report data.
	;;; Seems to import fine this way.
	finishpos =
	
	;;; tstext is the tournament summary text.
	tstext1 =
	tstext1 = 
	( LTrim
		PokerTracker 4 Tournament Summary
		Site: Yatahay Network
		Game: %line2%
		Tournament #: %line1%
		Started: %startyear%/%startmonth%/%startday%
		Finished: %endyear%/%endmonth%/%endday%
		
	)
	
	buyinIndex := line0 - 29
	buyin := line%buyinIndex%
	feeIndex := line0 - 25
	fee := line%feeIndex%
	StringTrimLeft, fee, fee, 1
	
	;;; Account for Sit&Crush fee which is not reported as rake
	SetFormat, FloatFast, 0.2
	adjFee := fee ;/ 0.75
	if (adjTheFee)
	{
		adjFee /= 0.75
	}
	

	tstext2 =
	tstext2 = 
	( LTrim
		Buyin: %buyin%
		Fee: $%adjFee%		
		Place: %finishpos%, Player: %ScreenName%, Won: $%winnings%,
	)
	
	;;; tspath is the path of the output tournament summary file to create.
	tspath = %OutputFolder%\T#%line1% - %buyin% + $%adjFee% - %tsdate% - Summary.txt

	;;; Overwrite existing summary.
	IfExist, %tspath%
	{
		FileDelete, %tspath%
	}
	
	;;; Write the tournament summary.
	FileAppend, %tstext1%%tstext2%, %tspath%
	if (not ErrorLevel)
	{
		TScount++
	}
}

;;; Report number of tournament summaries generated.
MsgBox, %TScount%  tournament summaries written to folder %OutputFolder%
return



;;; Shut it down!
GuiClose:
ExitApp
return

08-31-2016 , 02:21 PM

#74

jackpotfind

stranger

Join Date: Aug 2016 Posts: 1

Help me please. The VPN client can not find the menu of the first four points. Obviously, I'm looking for is not there where it is necessary. Please make screenshots of the first four steps!

08-31-2016 , 03:08 PM

#75

Max Cut

Guest

Posts: n/a

Quote:

Originally Posted by jackpotfind

Help me please. The VPN client can not find the menu of the first four points. Obviously, I'm looking for is not there where it is necessary. Please make screenshots of the first four steps!

1. Navigate to "My Account" --> "Transactions".